;*****************************************************
		; Опрос 4-х кнопок без фильтрации дребезга / @ Fahivec
B_Scan:	; Кнопки подключены между линиями данных LCD. 39 команд

.def Button	= R15	; переменная сканирования кнопок
.equ D7 = 3			; Порт данных MCU бит 3 = Шина данных LCD бит D7
;.equ D6 = 2
.equ D5 = 1			; Порт данных MCU бит 1 = Шина данных LCD бит D5
;.equ D4 = 0
	Push Temp
	Push Temp1
	cbi CMD_PORT,RW ; LCD на запись = D4..В7 на вход (Hi-Z)
	rcall PortIn	; библиотека DI HALT'а LCD4.asm (PullUp=1). 7 команд
; Scan 1
	cbi DATA_PORT,D7	; LCD_D7=0
	sbi DATA_DDR,D7		; выход
	nop	; подождать пока линия будет действительно на "0"
	nop	; из-за паразитивных ёмкостей.
	nop	; при более высоких тактовых частотах добавить еще несколько NOP-ов!
	nop	; при меньших можно сократить.
	in Temp, DATA_PIN	; считать состояние
	ori Temp, 0xFA	; маска для битов 0,2 (1111.1x1x)
	sec				; Flag Carry для ROL
	rol Temp		; сместить в биты 1,3 (1111.x1x1)
	sbi DATA_PORT,D7	; PullUp
	cbi DATA_DDR,D7		; снова вход
; Scan 2
	cbi DATA_PORT,D5	; LCD_D5=0
	sbi DATA_DDR,D5		; выход
	nop
	nop
	nop
	nop
	in Temp1, DATA_PIN	; считать состояние
	ori Temp1, 0xFA	; маска для битов 0,2 (1111.1x1x)
	sbi DATA_PORT,D5	; PullUp
	cbi DATA_DDR,D5		; снова вход

	and Temp, Temp1	; объединить оба скана (1111.xxxx)
	COM Temp		; инвертировать (0000.XXXX) - если ни одна не нажата =0x00
	mov Button, Temp	; результат в переменную
	pop Temp1
	pop Temp
	ret			; 32+7=39 команд
;****************************************************
