FT232: Как подружить 1-wire с компом

Устройств, работающих на шине 1-wire великое множество: ключи-таблетки, датчики температуры, память, RTC, АЦП…
Некоторые из них хочется подключить к компу. Но как? Неужели придется делать какой-то преобразователь на МК, или ставить специальную микросхему?!

Нет, все гораздо проще. Передавая через UART байты с разным коэфф. заполнения можно получить нужные по длительности импульсы. Таким образом можно эмулировать 1-wire. Идея в общем-то довольно известная, но я о ней узнал недавно, и думаю, что не только я один :)

Для того, чтобы UART порт мог работать как 1-wire, нужно прицепить пару деталей:



С RX мы будем принимать данные, которые сами передаем + изменения, вносимые слейвом. TX подключен так, чтобы не было конфликтов уровней на линии (когда TX в лог единице, а слейв тянет линию вниз). Плату под такое делать рука не поднимается, поэтому я применил скилл говноляпства:



Чтобы UART мог генерировать импульсы нужной длины, нам придется хитро переключать скорости:

RESET передаем так: бодрейт — 9600, предаем 0xF0. В случае если слейв сказал «привет», получим не то, что отправили.


Единичка (или чтение): бодрейт 115200, передаем 0xFF. Если слейв потянул линию вниз — получим что-то меньшее.


Ноль: бодрейт 115200, передаем 0x00.


--Все картинки я нагло скопипастил из аппноута от Максима.

Теперь, попробуем реализовать это на практике. Для примера я написал программу, которая опрашивает датчик DS18b20 и выдает на экран температуру:



Весь код приводить не буду, покажу лишь то, что связано с обменом данными.

Генерация RESET. Если кто-то откликнулся — функция возвращает true, иначе false.

function OneWire_reset: boolean;
begin
 Result := false;
 FT_Current_Baud := 9600;
 FT_Current_DataBits := 8;
 FT_Current_StopBits := FT_STOP_BITS_1;
 FT_Current_Parity := FT_PARITY_NONE;
 FT_Current_FlowControl := FT_FLOW_NONE;
 Set_USB_Device_BaudRate;
 Set_USB_Device_DataCharacteristics;
 Set_USB_Device_FlowControl;

 FT_Out_Buffer[0] := $F0;
 Write_USB_Device_Buffer(1);

 repeat
   Get_USB_Device_QueueStatus;
 until (FT_Q_Bytes > 0);

 Read_USB_Device_Buffer(1);

 if FT_In_Buffer[0] <> $F0 then Result := true;
end;

Передача 1 байта данных:

procedure OneWire_send_byte(DataToTransfer: byte);
var
 tmp_b: byte;
 i: integer;
begin
 FT_Current_Baud := 115200;
 Set_USB_Device_BaudRate;

 for I := 0 to 7 do
  if (DataToTransfer and (1 shl I)) <> 0 then
   FT_Out_Buffer[i] := $FF
  else
   FT_Out_Buffer[i] := $00;

  Write_USB_Device_Buffer(8);

 //RX у нас замкнут на TX, поэтому данные придут обратно,
 //и если их не прочитать - будут валяться в буфере FT232.
 repeat
   Get_USB_Device_QueueStatus;
 until (FT_Q_Bytes >= 8);

 Read_USB_Device_Buffer(8);

end;

Чтение байта:

function OneWire_read_byte(): byte;
var
 tmp_b: byte;
 i: integer;
begin
 Result := 0;
 FT_Current_Baud := 115200;
 Set_USB_Device_BaudRate;

 for I := 0 to 7 do
  FT_Out_Buffer[i] := $FF;

  Write_USB_Device_Buffer(8);

 repeat
   Get_USB_Device_QueueStatus;
 until (FT_Q_Bytes >= 8);

 Read_USB_Device_Buffer(8);

 for I := 0 to 7 do
  if FT_In_Buffer[i]<>$FF then
   Result := Result or (1 shl I);
   Result := not result;
end;

Остальной код + скомпилированную прогу можно взять тут. В папке _inc есть два ценных файла: One_wire.pas — реализация низкоуровневого обмена данными (ресет, чтение, запись); и DS18b20.pas — функции для работы с градусником. А вот, как это все работает:



P.S. Все вышесказаное применимо не только к FT232. Можно сделать тоже самое на железном COM порте или другом преобразователе…